Arduino Uno als 74HC4051 (MUX/DEMUX) tester

Geplaatst op 2019-10-04

74HC4051 testen

De 74HC4051 is een multiplexer / demultiplexer IC. Om deze te testen kan de Arduino Uno gebruikt worden met twee 74HC4051 ICs. De eerste IC fungeert als multiplexer, de tweede als demultiplexer.

Pinout

Pin	Label	Functie
1	A4	Kanaal in/uit
2	A6	Kanaal in/uit
3	A	Gemeenschappelijk in/uit
4	A7	Kanaal in/uit
5	A5	Kanaal in/uit
6	~E	Enable (negatief)
7	Vee	Negatieve voeding
8	GND	Grond (0V)
9	Vcc	Voeding (5V DC)
10	A2	Kanaal in/uit
11	A1	Kanaal in/uit
12	A0	Kanaal in/uit
13	A3	Kanaal in/uit
14	S0	Adreslijn bit 0
15	S1	Adreslijn bit 1
16	S2	Adreslijn bit 2

Digitaal testen

Alhoewel de 74HC4051 een analoog MUX/DEMUX is, kan deze niet analoog getest worden met de Arduino Uno, omdat deze geen analoge uitgangen heeft (DAC). Later in dit artikel, wordt beschreven hoe dit toch kan verwezenlijkt worden met een DAC breakout bord. Om digitaal te testen zijn dus enkel het Arduino bord en 2 ICs nodig.

Aansluiten

Leg pin 16 (Vcc) van beide ICs op 5VDC; pin 8 (GND) op 0V.

Leg pinnen 6 (~E) en 7 (Vee) van beide ICs eveneens op GND.

Verbind volgende pinnen van beide ICs met elkaar: 1,2,4,5,15,16,13,12 (A0..A7).

Verbind van beide ICs de pinnen 11 (S0) naar het Arduino bord op A0.

Verbind van beide ICs de pinnen 12 (S1) naar het Arduino bord op A1.

Verbind van beide ICs de pinnen 13 (S2) naar het Arduino bord op A2.

Van IC 1, verbind pin 3 (A) naar het Arduino bord op A4.

Van IC 2, verbind pin 3 (A) naar het Arduino bord op A5.

Arduino code

Gebruik volgende code voor de Arduino

Test 74HC4051 MUX/DEMUX met Arduino Uno

/****************************************************************
      Configuratie
****************************************************************/
#define pinS0   A0 // Address select 0
#define pinS1   A1 // Address select 1
#define pinS2   A2 // Address select 2
#define pinA_ic1  A4    // A pin on IC1
#define pinA_ic2  A5    // A pin on IC2
/*****   EINDE CONFIGUTATIE    *****/

// Poll timer
unsigned long lastPoll;

/****************************************************************
      SETUP
****************************************************************/
void setup()
{
  Serial.begin(115200);
  while (!Serial) {
    ; // Wacht op seriele monitor
  }
  Serial.println("--- Seriele monitor gestart ---");

  // Configureer pinnen als uitgangen
  pinMode(pinS0, OUTPUT);
  pinMode(pinS1, OUTPUT);
  pinMode(pinS2, OUTPUT);
  pinMode(pinA_ic1, OUTPUT);
  // Configureer pinnen als ingangen
  pinMode(pinA_ic2, INPUT);

  lastPoll = millis();
}

/****************************************************************
      LOOP
****************************************************************/
void loop()
{
  static byte byteCounter = 0;
  static bool writeBit;
  static bool readBit;
  String testResult;

  // Genereer willekeurig true of false
  writeBit = bool(random(0, 2));

  // Elke 500ms
  if (millis() - lastPoll >= 500)
  {
    // Selecteer adres
    selectAddress(byteCounter);

    // Schrijf bit naar IC 1
    digitalWrite(pinA_ic1, writeBit);

    // Lees bit van IC 2
    readBit = digitalRead(pinA_ic2);

    if (writeBit == readBit) {
      testResult = " -> OK";
    }
    else {
      testResult = " -> NIET OK";
    }
    

    // In de seriële monitor moet bit schrijf = bit lees
    Serial.print("Op adres " );
    Serial.print(byteCounter, BIN);
    Serial.print(" is schrijf (IC 1) vs lees (IC 2): " );
    Serial.print(writeBit);
    Serial.print(" / ");
    Serial.print(readBit);
    Serial.print(testResult);
    Serial.println();

    // Selecteer volgend adres 
    byteCounter++;
    if (byteCounter > 7) {
      byteCounter = 0;  // Reset counter at 1000 (count 0000 to 0111)
    }
    lastPoll = millis();
  }
}

/****************************************************************
      Zet de Sx pinnen om het gewenste adres te selecteren
****************************************************************/
void selectAddress(byte address) {
  // Lees adres bits
  bool S0 = bool(address >> 0 & 0x01); // Shift rechts en maskeer met 0x01
  bool S1 = bool(address >> 1 & 0x01);
  bool S2 = bool(address >> 2 & 0x01);

  // Zet adres lijnen correct
  digitalWrite(pinS0, S0);
  digitalWrite(pinS1, S1);
  digitalWrite(pinS2, S2);
}
//EINDE

Het resultaat is iets in dit genre:

Op adres 0 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 1 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 10 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 11 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 100 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 101 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 110 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 111 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 0 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 1 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 10 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 11 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK

Componenten

De componenten voor deze test:

Componenten lijst

74HC4051 multiplexer - 5 stuks Niet op voorraad (worden per 5 verkocht) € 3,60 Breadboard 400 punten - wit Niet op voorraad € 1,90 Male-Male jumper set 65 stuks Direct leverbaar € 2,95 Totaal € 8,45

Op dezelfde manier kan je de versie testen op het breakout board

SparkFun Multiplexer Breakout - 8-kanaals (74HC4051)De SparkFun Multiplexer Breakout biedt toegang tot alle pinnen en functies van de 74HC4051, een 8-kanaals analoge multiplexer / demultiplexer. Direct leverbaar € 4,10

Analoog testen

Om analoog te testen heb je een DAC nodig. Standaard heeft de Arduino Uno dit niet, maar met behulp van het “Adafruit MCP4725 (12bit DAC)” breakout bord, kan je dit eventueel verwezenlijken.

MCP4725 Breakout Board - 12-bits DAC met I2C-interfaceUw microcontroller heeft waarschijnlijk een ADC (analoog -> digitaal converter) maar heeft hij ook een DAC (digitaal -> analoog converter)? Nu kan het! Dit breakout-bord is voorzien van de gebruiksvriendelijke MCP4725 12-bits DAC. Levertijd 10 tot 30 werkdagen € 5,70

Aansluiten

De aansluiting dient dan aangepast te worden:
Leg pin 3 (A) van IC 1 op de uitgang van de MCP4725 (VOU) (in plaats van op A5)
Leg pin 3 (A) van IC 2 op pin A3 van het Arduino bord (in plaats van op A4).
Pinnen A4 (SCA) en A5 (SCL) van het Arduino bord, moeten aangesloten worden op SDA en SCL van de MCP4725.
Leg ook VDD en GND van het MCP4725 bord op respectievelijk 5V en GND.
Leg pin A0 van de MCP4725 op GND om I2C adres 0x62 te selecteren.
(Alternatief: A0 op 5V op adres 0x63 te selecteren.)

Adafruit bibliotheken

Om de Adafruit MCP4725 DAC aan te sturen, is het aangeraden de bijhorende bibliotheek van Adafruit te downloaden.
Deze kan je terugvinden op Github.

De code voor het analoge testen is dan als volgt:

Test 74HC4051 MUX/DEMUX met Arduino Uno en DAC

// Voeg MCP4725 DAC bibliotheek toe
#include <Wire.h>               // I2C library
#include >Adafruit_MCP4725.h>   // Adafruit library for MCP4725 (DAC)
Adafruit_MCP4725 dac;

/****************************************************************
      Configuratie
****************************************************************/
#define pinS0   A0 // Address select 0
#define pinS1   A1 // Address select 1
#define pinS2   A2 // Address select 2
#define pinA_ic2  A3    // A pin on IC2
/*****   EINDE CONFIGUTATIE    *****/

// Poll timer
unsigned long lastPoll;

/****************************************************************
      SETUP
****************************************************************/
void setup()
{
  Serial.begin(115200);
  while (!Serial) {
    ; // Wacht op seriele monitor
  }
  Serial.println("--- Seriele monitor gestart ---");

  // Configureer pinnen als uitgangen
  pinMode(pinS0, OUTPUT);
  pinMode(pinS1, OUTPUT);
  pinMode(pinS2, OUTPUT);

  dac.begin(0x62);  // MCP4725, pin A0 ligt op GND
  // dac.begin(0x63);  // MCP4725, pin A0 ligt op 5V

  lastPoll = millis();
}

/****************************************************************
      LOOP
****************************************************************/
void loop()
{
  static byte byteCounter = 0;
  uint16_t writeChannel; // 12 bit (0-4095)
  uint16_t readChannel;  // 10 bit (0-1023)
  String testResult;

  // Genereer willekeurige analoge uitgang waarde
  writeChannel = random(0, 4096); // random 0-4095 (!)

  // Elke 500ms
  if (millis() - lastPoll >= 500)
  {
    // Selecteer adres
    selectAddress(byteCounter);

    // Schrijf naar DAC
    dac.setVoltage(writeChannel, false);

    // Lees analoge waarde van analoge ingang op Arduino
    readChannel = analogRead(pinA_ic2);

    // Converteer waarden naar volt
    writeChannel = map(writeChannel, 0, 4095, 0, 500);
    readChannel = map(readChannel, 0, 1023, 0, 500);

    // Zijn beide waarden gelijk ?
    if (writeChannel == readChannel) {
      testResult = " -> OK";
    }
    else {
      testResult = " -> NIET OK";
    }

    // In de seriële monitor moet schrijf waarde = lees waarde
    Serial.print("Op adres " );
    Serial.print(byteCounter, BIN);
    Serial.print(" is schrijf (IC 1) vs lees (IC 2): " );
    Serial.print(float(writeChannel)/100);
    Serial.print(" / ");
    Serial.print(float(readChannel)/100);
    Serial.print(testResult);
    Serial.println();

    // Selecteer volgend adres 
    byteCounter++;
    if (byteCounter > 7) {
      byteCounter = 0;  // Reset counter at 1000 (count 0000 to 0111)
    }
    lastPoll = millis();
  }
}

/****************************************************************
      Set the Sx pins to select proper address
****************************************************************/
void selectAddress(byte address) {
  // Lees adres bits
  bool S0 = bool(address >> 0 & 0x01); // Shift rechts en maskeer met 0x01
  bool S1 = bool(address >> 1 & 0x01);
  bool S2 = bool(address >> 2 & 0x01);

  // Zet adres lijnen correct
  digitalWrite(pinS0, S0);
  digitalWrite(pinS1, S1);
  digitalWrite(pinS2, S2);
}
//EINDE

Het resultaat op de seriële monitor is in dit genre:

Op adres 10 is schrijf (IC 1) vs lees (IC 2): 3.40 / 3.40 -> OK
Op adres 11 is schrijf (IC 1) vs lees (IC 2): 4.21 / 4.21 -> OK
Op adres 100 is schrijf (IC 1) vs lees (IC 2): 0.08 / 0.08 -> OK
Op adres 101 is schrijf (IC 1) vs lees (IC 2): 1.54 / 1.54 -> OK
Op adres 110 is schrijf (IC 1) vs lees (IC 2): 1.53 / 1.53 -> OK
Op adres 111 is schrijf (IC 1) vs lees (IC 2): 4.02 / 4.02 -> OK
Op adres 0 is schrijf (IC 1) vs lees (IC 2): 0.82 / 0.82 -> OK
Op adres 1 is schrijf (IC 1) vs lees (IC 2): 0.93 / 0.93 -> OK
Op adres 10 is schrijf (IC 1) vs lees (IC 2): 3.72 / 3.72 -> OK
Op adres 11 is schrijf (IC 1) vs lees (IC 2): 1.35 / 1.35 -> OK
Op adres 100 is schrijf (IC 1) vs lees (IC 2): 2.64 / 2.64 -> OK
Op adres 101 is schrijf (IC 1) vs lees (IC 2): 1.29 / 1.29 -> OK
Op adres 110 is schrijf (IC 1) vs lees (IC 2): 2.89 / 2.88 -> NIET OK
Op adres 111 is schrijf (IC 1) vs lees (IC 2): 3.54 / 3.54 -> OK
Op adres 0 is schrijf (IC 1) vs lees (IC 2): 4.24 / 4.24 -> OK
Op adres 1 is schrijf (IC 1) vs lees (IC 2): 1.51 / 1.51 -> OK
Op adres 10 is schrijf (IC 1) vs lees (IC 2): 4.20 / 4.20 -> OK

Er zullen af en toe “foutjes” zijn door afrondingen en onnauwkeurigheden. Zo zie je bijvoorbeeld dat 2,89V niet gelijk is aan 2,88V. Echter in combinatie met alle andere succesvolle resultaten, kan je aannemen dat de MUX/DEMUX perfect werkt.

Geschreven door Arashi Website

Arduino Uno als 74HC4051 (MUX/DEMUX) tester

74HC4051 testen

Pinout

Digitaal testen

Aansluiten

Arduino code

Test 74HC4051 MUX/DEMUX met Arduino Uno

Componenten

Componenten lijst

Analoog testen

Aansluiten

Adafruit bibliotheken

Test 74HC4051 MUX/DEMUX met Arduino Uno en DAC

Reacties