Bouw zelf een Bluetooth Lichtkrant

Geplaatst op 2017-11-13

Voorbeeld lichtkrant

Benodigdheden

Arduino Uno R3 - clone Direct leverbaar Of een Arduino Nano € 11,50 MAX7219 4x Dot matrix module Direct leverbaar Dit is het display, je hebt er minimaal 1 nodig, 2 is nog mooier! € 10,20 HC-06 Bluetooth module met adapter - clone Direct leverbaar Dit is de HC-06 Bluetooth Slave, je hebt er 1 nodig € 8,50 5,6KΩ Metaalfilm weerstand 1/4W - 100 stuks Niet op voorraad De spanningsdeler voor de Bluetooth module € 1,45 10KΩ Metaalfilm weerstand 1/4W - 10 stuks Direct leverbaar De spanningsdeler voor de Bluetooth module € 1,75 Mean Well SGA12E09-P1J adapter - 9V 1,33A Direct leverbaar Voor extra power, USB kan niet voldoende leveren € 14,00 DC socket inbouw 5,5mm x 2,1mm - 5 stuks Direct leverbaar € 2,50 Totaal € 49,90

Het Schema:

In het schema zie je hoe alles aangesloten moet worden. Als je nu al een draaierig gevoel krijgt van al die draadjes, kijk dan niet te veel naar het geheel maar probeer de modules één voor één te beschouwen en aan te sluiten. Je zult zien dat het mee valt.

In het schema staat slechts één viervoudige dot matrix led module, in werkelijkheid kun je er twee aan elkaar koppelen voor een dubbele breedte!

Aansluitschema lichtkrant

De bluetooth module vergt wel iets extra aandacht. De bluetooth communicatiesignalen (TX en RX) werken namelijk op 3,3 volt terwijl de Arduino met 5 volt werkt. De twee weerstanden zorgen ervoor dat de 5 volt van Arduino wordt teruggebracht tot ongeveer 3,3 volt.

De voeding:
Je ziet dat er een 5 volt voeding gebruikt wordt. Dat moet. Een Arduino, aangesloten op USB kan niet genoeg stroom leveren om de led matrix te voeden, zeker niet bij een dubbele matrix.

Arduino Library en Sketch:

De Arduino sketch maakt gebruik van twee externe libraries, om deze te installeren zoek je in de library manager naar MD_MAX72xx. Installeer vervolgens MD_Max72xx en MD_Parola

Lichtkrant USB Arduino Library

De juiste module instellen:
Na de installatie van de libraries, moeten we de MD_Max72xx library vertellen welke led matrix module wij gebruiken.

Ga op de harde schijf op zoek naar het bestand: MD_MAX72xx.h
(waarschijnlijk in de folder C:\Users\jouw naam\Documents\Arduino\libraries\MD_MAX72XX\src\)

//Op regel 214, zie je staan:   
#define   USE_PAROLA_HW   1, verander die 1 in 0

//Op regel 237 zie je staan: 
#define   USE_FC16_HW   0,   verander die 0 in 1.

De Arduino Sketch:

Dan kunnen we nu de sketch in laden.
Kopieer de sketch en plak de code in de Arduino software, selecteer de juiste com port en type Arduino en druk op upload!

#include <MD_Parola.h>
#include <MD_MAX72xx.h>
#include <SPI.h>
#include <SoftwareSerial.h>
#include <EEPROM.h>
#define MAX_DEVICES 8
#define CLK_PIN   13
#define DATA_PIN  11
#define CS_PIN    10

// Use softserial for the bluetooth module
SoftwareSerial mySerial(2, 3);

// HARDWARE SPI
MD_Parola LK = MD_Parola(CS_PIN, MAX_DEVICES);

uint8_t scrollSpeed = 30;    // default frame delay value
textEffect_t scrollEffect = PA_SCROLL_LEFT;
textPosition_t scrollAlign = PA_LEFT;
uint16_t scrollPause = 2000; // in milliseconds

// Global message buffers shared by Serial and Scrolling functions
#define  BUF_SIZE  75
char curMessage[BUF_SIZE];
char newMessage[BUF_SIZE];
bool newMessageAvailable = false;

void setup()
{
  // Enable the next line to clear the message from eeprom.
  // EEPROM.write(0,1);
  
  mySerial.begin(9600); 
  delay(500);
  
  // The next line configures the BT-04 (BT-06) Module to NOT report connection status. 
  mySerial.write("\r\nAT+ENABLEIND0\r\n"); 
  delay(100);
  ClearRXbuffer();
  
  // change the name of the BT-04 (BT-06) device, this will not work for HC-06
  mySerial.write("AT+NAMELichtkrant01\r\n"); 
  delay(100);
  ClearRXbuffer();
  
  LK.begin();
  LK.displayClear();
  LK.displaySuspend(false);
  LK.displayText(curMessage, scrollAlign, scrollSpeed, scrollPause, scrollEffect, scrollEffect);  

  // Get the last message from EEPROM
  getMessageFromEeprom();
}


void loop()
{  
  readSerial();
  if (LK.displayAnimate())
  {
    if (newMessageAvailable)
    {
      strcpy(curMessage, newMessage);
      newMessageAvailable = false;
      storeMessageInEeprom();
    }
    LK.displayReset();
  }
}


  
void readSerial(void) {
  static char *cp = newMessage;
  while (mySerial.available())  
  {
    *cp = (char)mySerial.read();
    if ( (*cp == '\r') || (*cp == '\n') || (cp - newMessage >= BUF_SIZE-2)) // end of message character or full buffer
    {
      *cp = '\0'; // end the string   
      cp = newMessage;
      newMessageAvailable = true;
      mySerial.print("Nieuwe Boodschap = ");
      mySerial.println(newMessage);
      ClearRXbuffer();
    }
    else  // move char pointer to next position
      cp++;
  }
}


void storeMessageInEeprom(){
  // Store the message in EEPROM
  EEPROM.write(0,251);
  int i=0;
  char c=curMessage[i];
  while (c !=0){
    EEPROM.write(i+1,c);
    i++;
    c=curMessage[i];
    }
    EEPROM.write(i+1,0);
}

void getMessageFromEeprom(){
  if (EEPROM.read(0)!=251){
    strcpy(curMessage, "Hello! Please Send new message over bluetooth");
    newMessage[0] = '\0';
    } else {      
      int i=0;
      char c = EEPROM.read(i+1);
      while (c!=0){
        curMessage[i++]=c;
        c = EEPROM.read(i+1);
        }
        curMessage[i] = '\0';
        newMessageAvailable=false;         
    }
}

void ClearRXbuffer(){
  while (mySerial.available()){
    char c=mySerial.read(); 
    delay(5);
    } 
}

Als alles goed is (en waarom zou dat niet?) zie je nu de boodschap “Hello, please send a new message over bluetooth”. Hoogste tijd dus om de Android App te installeren op je telefoon en via bluetooth een nieuwe boodschap te sturen!

De Android App:

Om de tekst op de lichtkrant te veranderen hebben we een Bluetooth terminal programma nodig, bijvoorbeeld de Serial Bluetooth Terminal van Kai Morich, via de App Store.

Serial Bluetooth Terminal

De werking van de App spreekt redelijk voor zich maar in de video laat ik het stap voor stap zien.

Bluetooth terminal

Opgelet: Apple’s iOS kan niet verbinden met de gebruikte bluetooth module, dit werkt dus alleen met Android apparaten.

Bekijk de video

Zijn er nog onduidelijkheden? In deze video kun je alles nog eens rustig bekijken.

Geschreven door Bart Venneker Website | Youtube Bart Venneker is elektronica hobbyist en maakt leerzame video’s over elektronica, Arduino en 3d printers.

Reacties

Ad Laat

De aanpassingen in de libery zijn helaas niet te vinden waardoor de lichtkrant niet werkt, jammer! Is er misschien een andere versie gebruikt?Groetjes, Ad de Laat

Geplaatst op 19 november 2023

